En las siguientes tablas se proporciona información acerca de los distintos tipos de fórmulas que puede implementar en un campo calculado mediante el uso de la propiedad Formula de la clase Microsoft.SharePoint.SPFieldCalculated.
 Nota |
|---|
Las fórmulas de Microsoft SharePoint Foundation para campos calculados se basan en las funciones y sintaxis de Microsoft Excel. No obstante, Microsoft solo es compatible con las funciones mencionadas en esta página para el uso en campos calculados de SharePoint Foundation. Por ejemplo, la función EXTRAE de Excel no es compatible.
|
 Importante |
|---|
Todas las fórmulas de ejemplo de este tema usan la coma "," como carácter delimitador de parámetros. En algunos países, la coma se reserva como marca decimal. En tal caso, los usuarios que crean un campo calculado deben usar el punto y coma ";" como carácter delimitador. Independientemente del carácter que se use, cuando se crea el campo, la fórmula funciona en listas de los sitios web de SharePoint en cualquier lugar del mundo. SharePoint modifica automáticamente el carácter delimitador que se adecúa al idioma/cultura de la página actual. Por ejemplo, si suponemos que la siguiente fórmula se crea en un sitio cuyo idioma de configuración es fr-fr (Francia): =IF(Number1>Number2;5;10). Si la cultura del sitio web se cambia a continuación a en-us (Estados Unidos), la fórmula cambia automáticamente a: =IF(Number1>Number2,5,10).
|
Puede usar las siguientes fórmulas para probar la condición de una instrucción y devolver un valor Sí o No, probar un valor alternativo como Correcto o Incorrecto o devolver un espacio en blanco o un guión para representar un valor nulo.
Determinar si un número es mayor o menor que otro número
Use la función IF para realizar esta comparación.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
15000
|
9000
|
=[Columna1]>[Columna2]
|
¿Es Columna1 mayor que Columna2? (Sí)
|
15000
|
9000
|
=IF([Columna1]<=[Columna2], "Correcto", "Incorrecto")
|
¿Es Columna1 menor o igual que Columna2? (Incorrecto)
|
Devolver un valor lógico después de comparar el contenido de las columnas
Si un resultado es un valor lógico (Sí o No), use las funciones AND, OR y NOT.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
15
|
9
|
8
|
=AND([Columna1]>[Columna2], [Columna1]<[Columna3])
|
¿Es 15 mayor que 9 y menor que 8? (No)
|
15
|
9
|
8
|
=OR([Columna1]>[Columna2], [Columna1]<[Columna3])
|
¿Es 15 mayor que 9 o menor que 8? (Sí)
|
15
|
9
|
8
|
=NOT([Columna1]+[Columna2]=24)
|
¿Es 15 más 9 no igual a 24? (No)
|
Si el resultado es otro cálculo o cualquier otro valor distinto de Sí o No, use las funciones IF, AND y OR.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
15
|
9
|
8
|
=IF([Columna1]=15, "Correcto", "Incorrecto")
|
Si el valor de Columna1 es igual a 15, se devuelve "Correcto". (Correcto)
|
15
|
9
|
8
|
=IF(AND([Columna1]>[Columna2], [Columna1]<[Columna3]), "Correcto", "Incorrecto")
|
Si 15 es mayor que 9 y menor que 8, se devuelve "Correcto". (Incorrecto)
|
15
|
9
|
8
|
=IF(OR([Columna1]>[Columna2], [Columna1]<[Columna3]), "Correcto", "Incorrecto")
|
Si 15 es mayor que 9 o menor que 8, se devuelve "Correcto". (Correcto)
|
Mostrar ceros como espacios en blanco o guiones
Para mostrar un cero, realice un cálculo simple. Para mostrar un espacio en blanco o un guión, use la función IF.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
10
|
10
|
=[Columna1]-[Columna2]
|
El segundo número se resta del primero. (0)
|
15
|
9
|
=IF([Columna1]-[Columna2],[Columna1]-[Columna2],"-")
|
Devuelve un guión si el valor es cero. (-)
|
Ocultar los valores de error en las columnas
Para mostrar un guión, #N/A o NA en lugar de un valor de error, use la función ISERROR.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
10
|
0
|
=[Columna1]/[Columna2]
|
El resultado es un error (#DIV/0).
|
10
|
0
|
=IF(ISERROR([Columna1]/[Columna2]),"NA",[Columna1]/[Columna2])
|
Devuelve NA si el valor es un error.
|
10
|
0
|
=IF(ISERROR([Columna1]/[Columna2]),"-",[Columna1]/[Columna2])
|
Devuelve un guión si el valor es un error.
|
Puede usar las siguientes fórmulas para realizar cálculos basados en las fechas y horas, como la suma de un número de días, meses o años a una fecha, el cálculo de la diferencia entre dos fechas o la conversión de la hora en un valor decimal.
Sumar fechas
Para sumar un número de días a una fecha, use el operador de suma (+).
| Nota |
|---|
Al manipular fechas, el tipo devuelto de la columna calculada se debe establecer en Fecha y hora.
|
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
9/6/2007
|
3
|
=[Columna1]+[Columna2]
|
Suma 3 días a 9/6/2007 (12/6/2007).
|
10/12/2008
|
54
|
=[Columna1]+[Columna2]
|
Suma 54 días a 10/12/2008 (2/2/2009).
|
Para sumar un número de meses a una fecha, use las funciones DATE, YEAR, MONTH y DAY.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
9/6/2007
|
3
|
=DATE(YEAR([Columna1]),MONTH([Columna1])+[Columna2],DAY([Columna1]))
|
Suma 3 meses a 9/6/2007 (9/9/2007).
|
10/12/2008
|
25
|
=DATE(YEAR([Columna1]),MONTH([Columna1])+[Columna2],DAY([Columna1]))
|
Suma 25 meses a 10/12/2008 (10/1/2011).
|
Para sumar un número de años a una fecha, use las funciones DATE, YEAR, MONTH y DAY.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
9/6/2007
|
3
|
=DATE(YEAR([Columna1])+[Columna2],MONTH([Columna1]),DAY([Columna1]))
|
Suma 3 años a 9/6/2007 (9/6/2010).
|
10/12/2008
|
25
|
=DATE(YEAR([Columna1])+[Columna2],MONTH([Columna1]),DAY([Columna1]))
|
Suma 25 años a 10/12/2008 (10/12/2033).
|
Para sumar una combinación de días, meses y años a una fecha, use las funciones DATE, YEAR, MONTH y DAY.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
9/6/2007
|
=DATE(YEAR([Columna1])+3,MONTH([Columna1])+1,DAY([Columna1])+5)
|
Suma 3 años, 1 mes y 5 días a 9/6/2007 (14/7/2010).
|
10/12/2008
|
=DATE(YEAR([Columna1])+1,MONTH([Columna1])+7,DAY([Columna1])+5)
|
Suma 1 año, 7 meses y 5 días a 10/12/2008 (15/7/2010).
|
Calcular la diferencia entre dos fechas
Use la función DATEDIF para realizar este cálculo.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
01-ene-1995
|
15-jun-1999
|
=DATEDIF([Columna1], [Columna2],"d")
|
Devuelve el número de días entre las dos fechas (1626).
|
01-ene-1995
|
15-jun-1999
|
=DATEDIF([Columna1], [Columna2],"ym")
|
Devuelve el número de meses entre las fechas y se omite la parte del año (5).
|
01-ene-1995
|
15-jun-1999
|
=DATEDIF([Columna1], [Columna2],"yd")
|
Devuelve el número de días entre las fechas y se omite la parte del año (165).
|
Calcular la diferencia entre dos horas
Para presentar el resultado en el formato de hora estándar (horas:minutos:segundos), use el operador de resta (-) y la función TEXT. Para que este método funcione, las horas no pueden superar 24 y los minutos y segundos no pueden superar 60.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
09/06/2007 10:35 a.m.
|
09/06/2007 3:30 p.m.
|
=TEXT([Columna2]-[Columna1],"h")
|
Horas entre dos horas (4).
|
09/06/2007 10:35 a.m.
|
09/06/2007 3:30 p.m.
|
=TEXT([Columna2]-[Columna1],"h:mm")
|
Horas y minutos entre dos horas (4:55).
|
09/06/2007 10:35 a.m.
|
09/06/2007 3:30 p.m.
|
=TEXT([Columna2]-[Columna1],"h:mm:ss")
|
Horas, minutos y segundos entre dos horas (4:55:00).
|
Para presentar el resultado en un total basado en una unidad de tiempo, use la función INT o las funciones HOUR, MINUTE o SECOND.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
09/06/2007 10:35 a.m.
|
10/06/2007 3:30 p.m.
|
=INT(([Columna2]-[Columna1])*24)
|
Total de horas entre dos horas (28).
|
09/06/2007 10:35 a.m.
|
10/06/2007 3:30 p.m.
|
=INT(([Columna2]-[Columna1])*1440)
|
Total de minutos entre dos horas (1735).
|
09/06/2007 10:35 a.m.
|
10/06/2007 3:30 p.m.
|
=INT(([Columna2]-[Columna1])*86400)
|
Total de segundos entre dos horas (104100).
|
09/06/2007 10:35 a.m.
|
10/06/2007 3:30 p.m.
|
=HOUR([Columna2]-[Columna1])
|
Horas entre dos horas si la diferencia no supera 24 (4).
|
09/06/2007 10:35 a.m.
|
10/06/2007 3:30 p.m.
|
=MINUTE([Columna2]-[Columna1])
|
Minutos entre dos horas si la diferencia no supera 60 (55).
|
09/06/2007 10:35 a.m.
|
10/06/2007 3:30 p.m.
|
=SECOND([Columna2]-[Columna1])
|
Segundos entre dos horas si la diferencia no supera 60 (0).
|
Convertir horas
Para convertir horas del formato de hora estándar a un número decimal, use la función INT.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
10:35 a.m.
|
=([Columna1]-INT([Columna1]))*24
|
Número de horas desde las 12:00 a.m. (10,583333).
|
12:15 p.m.
|
=([Columna1]-INT([Columna1]))*24
|
Número de horas desde las 12:00 a.m. (12,25).
|
Para convertir horas de un número decimal al formato de hora estándar (horas:minutos:segundos), use el operador de división y la función TEXT.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
23:58
|
=TEXT(Columna1/24, "hh:mm:ss")
|
Horas, minutos y segundos desde las 12:00 a.m. (00:59:55).
|
2:06
|
=TEXT(Columna1/24, "h:mm")
|
Horas y minutos desde las 12:00 a.m. (0:05).
|
Insertar fechas del calendario juliano
Una fecha del calendario juliano hace referencia a un formato de fecha que es una combinación del año actual y el número de días desde el comienzo del año. Por ejemplo, 1 de enero de 2007 se representa como 2007001 y 31 de diciembre de 2007 se representa como 2007365. Este formato no se basa en el calendario juliano.
Para convertir una fecha a una fecha del calendario juliano, use las funciones TEXT y DATEVALUE.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
23/06/07
|
=TEXT([Columna1],"yy")&TEXT(([Columna1]-DATEVALUE("1/1/"& TEXT([Columna1],"yy"))+1),"000")
|
Fecha en formato de calendario juliano con un año de dos dígitos (07174).
|
23/06/07
|
=TEXT([Columna1],"yyyy")&TEXT(([Columna1]-DATEVALUE("1/1/"&TEXT([Columna1],"yy"))+1),"000")
|
Fecha en formato de calendario juliano con un año de cuatro dígitos (2007174).
|
Para convertir una fecha a una fecha del calendario juliano usada en astronomía, use la constante 2415018,50. Esta fórmula sólo funciona para las fechas posteriores al 1/3/1901 y si se usa el sistema de fechas 1900.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
23/06/07
|
=[Columna1]+2415018,50
|
Fecha en formato del calendario juliano usada en astronomía (2454274,50).
|
Mostrar fechas como días de la semana
Para convertir las fechas en el texto del día de la semana, use las funciones TEXT y WEEKDAY.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
19-feb-2007
|
=TEXT(WEEKDAY([Columna1]), "dddd")
|
Calcula el día de la semana para la fecha y devuelve el nombre completo del día (lunes).
|
3-ene-2008
|
=TEXT(WEEKDAY([Columna1]), "ddd")
|
Calcula el día de la semana para la fecha y devuelve el nombre abreviado del día (jue).
|
Puede usar las siguientes fórmulas para realizar varios cálculos matemáticos, como sumar, restar, multiplicar y dividir números, calcular el promedio o la mediana de los números, redondear un número y contar valores.
Sumar números
Para sumar los números de dos o más columnas de una fila, use el operador de suma (+) o la función SUM.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
6
|
5
|
4
|
=[Columna1]+[Columna2]+[Columna3]
|
Suma los valores de las tres primeras columnas (15).
|
6
|
5
|
4
|
=SUM([Columna1],[Columna2],[Columna3])
|
Suma los valores de las tres primeras columnas (15).
|
6
|
5
|
4
|
=SUM(IF([Columna1]>[Columna2], [Columna1]-[Columna2], 10), [Columna3])
|
Si Columna1 es mayor que Columna2, suma la diferencia y Columna3. Si no, se suman 10 y Columna3 (5).
|
Restar números
Para restar los números de dos o más columnas de una fila, use el operador de resta (-) o la función SUM con números negativos.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
15000
|
9000
|
-8000
|
=[Columna1]-[Columna2]
|
Resta 9000 de 15000 (6000).
|
15000
|
9000
|
-8000
|
=SUM([Columna1], [Columna2], [Columna3])
|
Suma los números de las tres primeras columnas, incluidos los valores negativos (16000).
|
Calcular la diferencia entre dos números como un porcentaje
Use los operadores de resta (-) y división (/), y la función ABS.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
2342
|
2500
|
=([Columna2]-[Columna1])/ABS([Columna1])
|
Cambio de porcentaje (6,75% o 0,06746).
|
Multiplicar números
Para multiplicar los números de dos o más columnas de una fila, use el operador de multiplicación (*) o la función PRODUCT.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
5
|
2
|
=[Columna1]*[Columna2]
|
Multiplica los números de los dos primeras columnas (10).
|
5
|
2
|
=PRODUCT([Columna1], [Columna2])
|
Multiplica los números de los dos primeras columnas (10).
|
5
|
2
|
=PRODUCT([Columna1],[Columna2],2)
|
Multiplica los números de las dos primeras columnas y el número 2 (20).
|
Dividir números
Para dividir los números de dos o más columnas de una fila, use el operador de división (/).
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
15000
|
12
|
=[Columna1]/[Columna2]
|
Divide 15000 entre 12 (1250).
|
15000
|
12
|
=([Columna1]+10000)/[Columna2]
|
Suma 15000 y 10000, y divide el total entre 12 (2083).
|
Calcular el promedio de los números
El promedio se llama también media. Para calcular el promedio de los números de dos o más columnas de una fila, use la función AVERAGE.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
6
|
5
|
4
|
=AVERAGE([Columna1], [Columna2],[Columna3])
|
Promedio de los números de las tres primeras columnas (5).
|
6
|
5
|
4
|
=AVERAGE(IF([Columna1]>[Columna2], [Columna1]-[Columna2], 10), [Columna3])
|
Si Columna1 es mayor que Columna2, calcule el promedio de la diferencia y Columna3. Si no, calcule el promedio del valor 10 y Columna3 (2,5).
|
Calcular la mediana de los números
La mediana es el valor central de un intervalo ordenado de números. Use la función MEDIAN para calcular la mediana de un grupo de números.
A
|
B
|
C
|
D
|
E
|
F
|
Fórmula
|
Descripción (resultado)
|
|---|---|---|---|---|---|---|---|
10
|
7
|
9
|
27
|
0
|
4
|
=MEDIAN(A, B, C, D, E, F)
|
Mediana de los números de las primeras seis columnas (8).
|
Calcular el número menor o mayor de un intervalo
Para calcular el número menor o mayor de dos o más columnas de una fila, use las funciones MIN y MAX.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
10
|
7
|
9
|
=MIN([Columna1], [Columna2], [Columna3])
|
Número menor (7).
|
10
|
7
|
9
|
=MAX([Columna1], [Columna2], [Columna3])
|
Número mayor (10).
|
Contar valores
Para contar valores numéricos, use la función COUNT.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
Manzana
|
12/12/2007
|
=COUNT([Columna1], [Columna2], [Columna3])
|
Cuenta el número de columnas que contienen valores numéricos. Excluye los valores de fecha y hora, texto y nulos (0).
| |
12 $
|
#DIV/0!
|
1,01
|
=COUNT([Columna1], [Columna2], [Columna3])
|
Cuenta el número de columnas que contienen valores numéricos, pero excluye los valores de error y los valores lógicos (2).
|
Aumentar o reducir un número en un porcentaje
Use el operador de porcentaje (%) para realizar este cálculo.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
23
|
3%
|
=[Columna1]*(1+5%)
|
Aumenta el número de Columna1 en un 5% (24,15).
|
23
|
3%
|
=[Columna1]*(1+[Columna2])
|
Aumenta el número de Columna1 en el valor de porcentaje de Columna2: 3% (23,69).
|
23
|
3%
|
=[Columna1]*(1-[Columna2])
|
Reduce el número de Columna1 en el valor de porcentaje de Columna2: 3% (22,31).
|
Elevar un número a una potencia
Use el operador exponencial (^) o la función POWER para realizar este cálculo.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
5
|
2
|
=[Columna1]^[Columna2]
|
Calcula cinco al cuadrado (25).
|
5
|
3
|
=POWER([Columna1], [Columna2])
|
Calcula cinco al cubo (125).
|
Redondear un número
Para redondear hacia arriba un número, use la función ROUNDUP, ODD o EVEN.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
20,3
|
=ROUNDUP([Columna1],0)
|
Redondea 20,3 hacia arriba hasta el número entero más próximo (21).
|
-5,9
|
=ROUNDUP([Columna1],0)
|
Redondea -5,9 hacia arriba hasta el número entero más próximo (-5).
|
12,5493
|
=ROUNDUP([Columna1],2)
|
Redondea 12,5493 hacia arriba hasta la centésima más próxima, con dos decimales (12,55).
|
20,3
|
=EVEN([Columna1])
|
Redondea 20,3 hacia arriba hasta el número par más próximo (22).
|
20,3
|
=ODD([Columna1])
|
Redondea 20,3 hacia arriba hasta el número impar más próximo (21).
|
Para redondear hacia abajo un número, use la función ROUNDDOWN.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
20,3
|
=ROUNDDOWN([Columna1],0)
|
Redondea 20,3 hacia abajo hasta el número entero más próximo (20).
|
-5,9
|
=ROUNDDOWN([Columna1],0)
|
Redondea -5,9 hacia abajo hasta el número entero más próximo (-6).
|
12,5493
|
=ROUNDDOWN([Columna1],2)
|
Redondea 12,5493 hacia abajo hasta la centésima más próxima, con dos decimales (12,54).
|
Para redondear un número hasta el número o la fracción más próximos, use la función ROUND.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
20,3
|
=ROUND([Columna1],0)
|
Redondea 20,3 hacia abajo porque la parte fraccionaria es menor que 0,5 (20).
|
5,9
|
=ROUND([Columna1],0)
|
Redondea 5,9 hacia arriba porque la parte fraccionaria es mayor que 0,5 (6).
|
-5,9
|
=ROUND([Columna1],0)
|
Redondea -5,9 hacia abajo porque la parte fraccionaria es menor que -0,5 (-6).
|
1,25
|
=ROUND([Columna1], 1)
|
Redondea el número hasta la décima más próxima (un decimal). Dado que la parte que se va a redondear es 0,05 o mayor, el número se redondea hacia arriba (resultado: 1,3).
|
30,452
|
=ROUND([Columna1], 2)
|
Redondea el número hasta la centésima más próxima (dos decimales). Dado que la parte que se va a redondear, 0,002, es menor que 0,005, el número se redondea hacia abajo (resultado: 30,45).
|
Para redondear un número hasta el dígito significativo por encima de 0, use las funciones ROUND, ROUNDUP, ROUNDDOWN, INT y LEN.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
5492820
|
=ROUND([Columna1],3-LEN(INT([Columna1])))
|
Redondea el número hasta 3 dígitos significativos (5490000).
|
22230
|
=ROUNDDOWN([Columna1],3-LEN(INT([Columna1])))
|
Redondea el número inferior hacia abajo hasta 3 dígitos significativos (22200).
|
5492820
|
=ROUNDUP([Columna1], 5-LEN(INT([Columna1])))
|
Redondea el número superior hacia arriba hasta 5 dígitos significativos (5492900).
|
Puede usar las siguientes fórmulas para manipular el texto (por ejemplo, puede combinar o concatenar los valores de varias columnas, comparar el contenido de las columnas, quitar caracteres o espacios, y repetir caracteres).
Cambiar las mayúsculas y minúsculas del texto
Para cambiar las mayúsculas y minúsculas del texto, use la función UPPER, LOWER o PROPER.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
cecilia Cornejo
|
=UPPER([Columna1])
|
Cambia el texto a mayúsculas (CECILIA CORNEJO).
|
cecilia Cornejo
|
=LOWER([Columna1])
|
Cambia el texto a minúsculas (cecilia cornejo).
|
cecilia Cornejo
|
=PROPER([Columna1])
|
Cambia el texto al tipo título (Cecilia Cornejo).
|
Combinar el nombre y los apellidos
Para combinar el nombre y los apellidos, use el operador de y comercial (&) o la función CONCATENATE.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
Enrique
|
Gil
|
=[Columna1]&[Columna2]
|
Combina las dos cadenas (EnriqueGil).
|
Enrique
|
Gil
|
=[Columna1]&" "&[Columna2]
|
Combina las dos cadenas, separadas por un espacio (Enrique Gil).
|
Enrique
|
Gil
|
=[Columna2]&", "&[Columna1]
|
Combina las dos cadenas, separadas por una coma y un espacio (Gil, Enrique).
|
Enrique
|
Gil
|
=CONCATENATE([Columna2], ",", [Columna1])
|
Combina las dos cadenas, separadas por una coma (Gil,Enrique).
|
Combinar texto y números de distintas columnas
Para combinar texto y números, use la función CONCATENATE, el operador de y comercial (&) o la función TEXT y el operador de y comercial.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
Bermejo
|
28
|
=[Columna1]&" vendió "&[Columna2]&" unidades."
|
Combina el contenido anterior en una frase (Bermejo vendió 28 unidades).
|
Maldonado
|
40%
|
=[Columna1]&" vendió el "&TEXT([Columna2],"0%")&" del total de ventas."
|
Combina el contenido anterior en una frase (Maldonado vendió el 40% del total de ventas).
Nota La función TEXT anexa el valor con formato de Columna2 en lugar del valor subyacente, que es 0,4.
|
Bermejo
|
28
|
=CONCATENATE([Columna1]," vendió ",[Columna2]," unidades.")
|
Combina el contenido anterior en una frase (Bermejo vendió 28 unidades).
|
Combinar texto con una fecha u hora
Para combinar texto con una fecha u hora, use la función TEXT y el operador de y comercial (&).
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
Fecha de facturación
|
5-jun-2007
|
="Fecha del balance: "&TEXT([Columna2], "d-mmm-yyyy")
|
Combina el texto con una fecha (Fecha del balance: 5-jun-2007).
|
Fecha de facturación
|
5-jun-2007
|
=[Columna1]&" "&TEXT([Columna2], "mmm-dd-yyyy")
|
Combina el texto y la fecha de distintas columnas en una columna (Fecha de facturación: 5-jun-2007).
|
Comparar el contenido de las columnas
Para comparar una columna con otra o una lista de valores, use las funciones EXACT y OR.
Columna1
|
Columna2
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|
BD122
|
BD123
|
=EXACT([Columna1],[Columna2])
|
Compara el contenido de las dos primeras columnas (No).
|
BD122
|
BD123
|
=EXACT([Columna1], "BD122")
|
Compara el contenido de Columna1 y la cadena "BD122" (Sí).
|
Determinar si un valor de columna o una parte de la columna coincide con un texto específico
Para determinar si un valor de columna o una parte de la columna coincide con un texto específico, use las funciones IF, FIND, SEARCH e ISNUMBER.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
Cornejo
|
=IF([Columna1]="Cornejo", "Correcto", "Incorrecto")
|
Determina si Columna1 es Cornejo (Correcto).
|
Cornejo
|
=IF(ISNUMBER(FIND("j",[Columna1])), "Correcto", "Incorrecto")
|
Determina si Columna1 contiene la letra j (Correcto).
|
BD123
|
=ISNUMBER(FIND("BD",[Columna1]))
|
Determina si Columna1 contiene BD (Sí).
|
Contar las columnas que no están en blanco
Para contar las columnas que no están en blanco, use la función COUNTA.
Columna1
|
Columna2
|
Columna3
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|---|---|
Ventas
|
19
|
=COUNTA([Columna1], [Columna2])
|
Cuenta el número de columnas que no están en blanco (2).
| |
Ventas
|
19
|
=COUNTA([Columna1], [Columna2], [Columna3])
|
Cuenta el número de columnas que no están en blanco (2).
|
Quitar caracteres del texto
Para quitar caracteres del texto, use las funciones LEN, LEFT y RIGHT.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
Vitamina A
|
=LEFT([Columna1],LEN([Columna1])-2)
|
Devuelve 7 (9-2) caracteres, empezando por la izquierda (Vitamin).
|
Vitamina B1
|
=RIGHT([Columna1], LEN([Columna1])-8)
|
Devuelve 2 (10-8) caracteres, empezando por la derecha (B1).
|
Quitar espacios del principio y del final de una columna
Para quitar espacios de una columna, use la función TRIM.
Columna1
|
Fórmula
|
Descripción (resultado posible)
|
|---|---|---|
¡Hola!
|
=TRIM([Columna1])
|
Quita los espacios del principio y del final (¡Hola!).
|
Repetir un carácter de una columna
Para repetir un carácter de una columna, use la función REPT.
Fórmula
|
Descripción (resultado posible)
|
|---|---|
=REPT(".",3)
|
Repite un punto 3 veces (...).
|
=REPT("-",10)
|
Repite un guión 10 veces (----------).
|
Comments
Post a Comment